Classes:TeleportFog

The Teleport Fog is a special effect flash that is spawned when an actor teleports and, by default, when an actor morphs or unmorphs. Teleport Fogs set the teleporting actor as their target, so actor manipulation via pointers is possible. This includes when an actor (un)morphs.

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things:

You do not need to copy that actor, since it is already defined.
In fact, it's not just useless, it's actually harmful as it can cause problems.
If you want to modify it, or use a modified version, using inheritance is the way to go.
The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.
There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.

Classes: TeleportFog

ZScript definition

Note: The ZScript definition below is for reference and may be different in the current version of GZDoom.The most up-to-date version of this code can be found on GZDoom GitHub.

class TeleportFog : Actor
{
	default
	{
		+NOBLOCKMAP
		+NOTELEPORT
		+NOGRAVITY
		+ZDOOMTRANS
		RenderStyle "Add";
	}
	States
	{
	Spawn:
		TFOG ABABCDEFGHIJ 6 Bright;
		Stop;
	
	Raven:
		TELE ABCDEFGHGFEDC 6 Bright;
		Stop;

	Strife:
		TFOG ABCDEFEDCB 6 Bright;
		Stop;
	}
	
	override void PostBeginPlay ()
	{
		Super.PostBeginPlay ();
		A_StartSound ("misc/teleport", CHAN_BODY);
		switch (gameinfo.gametype)
		{
		case GAME_Hexen:
		case GAME_Heretic:
			SetStateLabel("Raven");
			break;

		case GAME_Strife:
			SetStateLabel("Strife");
			break;
			
		default:
			break;
		}
	}
	
}

DECORATE definition

Note: This is legacy code, kept here for reference only. DECORATE is still supported but no longer used by GZDoom. GZDoom internally uses the ZScript definition above.

ACTOR TeleportFog native
{
  +NOBLOCKMAP
  +NOTELEPORT
  +NOGRAVITY
  RenderStyle Add
  States
  {
  Spawn:
    TFOG ABABCDEFGHIJ 6 Bright
    Stop
  
  Raven:
    TELE ABCDEFGHGFEDC 6 Bright
    Stop
  
  Strife:
    TFOG ABCDEFEDCB 6 Bright
    Stop
  }
}

This article is issued from Zdoom. The text is licensed under Creative Commons - Attribution - Sharealike. Additional terms may apply for the media files.

Teleport fog
Actor type	SFX	Game
DoomEd Number	None	Class Name	TeleportFog