Classes:StrifeBishop

Classes: Actor → StrifeBishop
The Bishop is the second Strife Boss. This tall guy fires homing rockets, and has a little more health than a Crusader.

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things:

You do not need to copy that actor, since it is already defined.
In fact, it's not just useless, it's actually harmful as it can cause problems.
If you want to modify it, or use a modified version, using inheritance is the way to go.
The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.
There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.

DECORATE definition

ACTOR StrifeBishop
{
  Health 500
  PainChance 128
  Speed 8
  Radius 40
  Height 56
  Mass 500
  Monster
  +NOBLOOD
  +NOTDMATCH
  +FLOORCLIP
  +INCOMBAT
  +NOICEDEATH
  +NEVERRESPAWN
  DamageFactor "Fire", 0.5
  MinMissileChance 150
  MaxDropoffHeight 32
  SeeSound "bishop/sight"
  PainSound "bishop/pain"
  DeathSound "bishop/death"
  ActiveSound "bishop/active"
  DropItem "CrateOfMissiles", 256, 20
  Obituary "$OB_STFBISHOP" // "%o was blown away by the Bishop."
  States
  {
  Spawn:
    MLDR A 10 A_Look
    Loop
  See:
    MLDR AABBCCDD 3 A_Chase
    Loop
  Missile:
    MLDR E 3 A_FaceTarget
    MLDR F 2 Bright A_CustomMissile("BishopMissile", 64, 0, 0, CMF_AIMOFFSET)
    Goto See
  Pain:
    MLDR D 1 A_Pain
    Goto See
  Death:
    MLDR G 3 Bright
    MLDR H 5 Bright A_Scream
    MLDR I 4 Bright A_TossGib
    MLDR J 4 Bright A_Explode(64, 64, 1, 1)
    MLDR KL 3 Bright
    MLDR M 4 Bright A_NoBlocking
    MLDR N 4 Bright
    MLDR O 4 Bright A_TossGib
    MLDR P 4 Bright
    MLDR Q 4 Bright A_TossGib
    MLDR R 4 Bright
    MLDR S 4 Bright A_TossGib
    MLDR T 4 Bright
    MLDR U 4 Bright A_TossGib
    MLDR V 4 Bright A_SpawnItemEx("AlienSpectre2", 0, 0, 0, 0, 0, random[spectrespawn](0, 255)*0.0078125,
                                  0, SXF_NOCHECKPOSITION)
    Stop
  }
}

This article is issued from Zdoom. The text is licensed under Creative Commons - Attribution - Sharealike. Additional terms may apply for the media files.

The Bishop
Actor type	Monster	Game
DoomEd Number	187	Class Name	StrifeBishop
Conversation ID	64	Puzzle Item ID	N/A