Classes:Ironlich

An iron lich looks nothing like the traditional fantasy lich: they are gigantic helmeted iron skulls, animated by magic and blasting their targets with elemental attacks. Their native action A_LichAttack will result either in a powerful bite if the target is close enough, or in a spell otherwise: either a whirlwind, a ice ball that explodes into tiny shards, or a column of fireballs.

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things:
  1. You do not need to copy that actor, since it is already defined.
  2. In fact, it's not just useless, it's actually harmful as it can cause problems.
  3. If you want to modify it, or use a modified version, using inheritance is the way to go.
  4. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.
  5. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.
Iron lich
Actor type Monster Game
DoomEd Number 6 Class Name IronLich
Spawn ID 20 Identifier T_IRONLICH


Classes: IronLich

In Heretic.wad, the sprites are actually named HEAD* and are renamed at load-time by ZDoom.

DECORATE definition

 
ACTOR Ironlich
{
  Health 700
  Radius 40
  Height 72
  Mass 325
  Speed 6
  PainChance 32
  Monster
  +NOBLOOD
  +DONTMORPH
  +DONTSQUASH
  +BOSSDEATH
  SeeSound "ironlich/sight"
  AttackSound "ironlich/attack"
  PainSound "ironlich/pain"
  DeathSound "ironlich/death"
  ActiveSound "ironlich/active"
  Obituary "$OB_IRONLICH"
  HitObituary "$OB_IRONLICHHIT"
  DropItem "BlasterAmmo", 84, 10
  DropItem "ArtiEgg", 51, 0

  action native A_LichAttack();

  States
  {
  Spawn:
    LICH A 10 A_Look
    Loop
  See:
    LICH A 4 A_Chase
    Loop
  Missile:
    LICH A 5 A_FaceTarget
    LICH B 20 A_LichAttack
    Goto See
  Pain:
    LICH A 4
    LICH A 4 A_Pain
    Goto See
  Death:
    LICH C 7
    LICH D 7 A_Scream
    LICH EF 7
    LICH G 7 A_NoBlocking
    LICH H 7
    LICH I -1 A_BossDeath
    Stop
  }
}
This article is issued from Zdoom. The text is licensed under Creative Commons - Attribution - Sharealike. Additional terms may apply for the media files.